*****************************************************
	****         Crazy Cars - Custom Module,	 ****
	****        all adaptions by Wanted Team	 ****
	*****************************************************

	incdir	"dh2:include/"
	include 'misc/eagleplayer2.01.i'
	include 'hardware/intbits.i'
	include 'exec/exec_lib.i'

	SECTION Player,Code_C

CC_Start
	PLAYERHEADER PlayerTagArray

	dc.b	"$VER: Crazy Cars - Custom Module,",10
	dc.b	'adapted by Don Adan/Wanted Team',0
	even

PlayerTagArray
	dc.l	DTP_CustomPlayer,1
	dc.l	DTP_PlayerName,PlayerName
	dc.l	DTP_StartInt,StartInt
	dc.l	DTP_StopInt,StopInt
	dc.l	DTP_InitPlayer,InitPlayer
	dc.l	DTP_EndPlayer,EndPlayer
	dc.l	DTP_InitSound,InitSound
	dc.l	DTP_EndSound,EndSound
	dc.l	EP_Get_ModuleInfo,Get_ModuleInfo
	dc.l	TAG_DONE
PlayerName
	dc.b	"CustomPlay",0
Text
	dc.b	10
	dc.b	"               Crazy Cars",10
	dc.b	10
	dc.b	"    was designed & programmed by Eric CAEN.",10
	dc.b	"    Produced by Herve CAEN.",10
	dc.b	"    Graphics : Olivier CORVIOLE.",10
	dc.b	"    Thanks to Phil for his terrific music,",10
	dc.b	"    Arnaud for the blitter,",10
	dc.b	"    Gil for his haircut,",10
	dc.b	"    Alex for his intuition,",10
	dc.b	"    Ben for the hard-disk,",10
	dc.b	"    Alain F the Latin Lover,",10
	dc.b	"    Eric Z for the noise of his car,",10
	dc.b	"    David for the ices,",10
	dc.b	"    and Claire my girlfriend.",10
	dc.b	"    Dedicated to Macha.",10
	dc.b	10
	dc.b	"     (c) Titus / EH Productions 1987",0
	even

***************************************************************************
***************************** EP_Get_ModuleInfo ***************************
***************************************************************************

Get_ModuleInfo
	lea	InfoBuffer(PC),A0
	rts

InfoBuffer
	dc.l	MI_SpecialInfo,Text
	dc.l	MI_LoadSize,CC_End-CC_Start
	dc.l	0

***************************************************************************
***************************** DTP_InitPlayer ******************************
***************************************************************************

InitPlayer
	move.l	dtg_AudioAlloc(A5),A0
	jmp	(A0)

***************************************************************************
***************************** DTP_EndPlayer *******************************
***************************************************************************

EndPlayer
	move.l	dtg_AudioFree(A5),A0
	jmp	(A0)

***************************************************************************
***************************** DTP_InitSound *******************************
***************************************************************************

InitSound
	bra.w	Init

***************************************************************************
***************************** DTP_EndSound ********************************
***************************************************************************

EndSound
	lea	$DFF000,A0
	move.w	#15,$96(A0)
	moveq	#0,D0
	move.w	D0,$A8(A0)
	move.w	D0,$B8(A0)
	move.w	D0,$C8(A0)
	move.w	D0,$D8(A0)
	rts

***************************************************************************
***************************** DTP_StartInt ********************************
***************************************************************************

StartInt
	movem.l	D0/A6,-(A7)
	lea	InterruptStruct(PC),A1
	moveq	#INTB_AUD0,D0
	move.l	4.W,A6			; baza biblioteki exec do A6
	jsr	_LVOSetIntVector(A6)
	move.l	D0,Audio0
	movem.l	(A7)+,D0/A6
	move.w	#$8080,$DFF09A
	move.w	#$8001,$DFF096
	rts

InterruptStruct
	dc.l	0
	dc.l	0
	dc.b	NT_INTERRUPT
	dc.b	5			; priority
	dc.l	Name			; ID string
	dc.l	0
	dc.l	Interrupt
Name
	dc.b	'Crazy Cars Aud0 Interrupt',0,0
	even

Audio0
	dc.l	0

***************************************************************************
***************************** DTP_StopInt *********************************
***************************************************************************

StopInt
	lea	$DFF000,A0
	move.w	#1,$96(A0)
	move.w	#$80,$9A(A0)
	move.w	#$80,$9C(A0)
	moveq	#INTB_AUD0,D0
	move.l	Audio0(PC),A1
	move.l	A6,-(A7)
	move.l	4.W,A6
	jsr	_LVOSetIntVector(a6)
	move.l	(A7)+,A6
	rts

***************************************************************************
***************************** DTP_Intterrupt ******************************
***************************************************************************

Interrupt
	movem.l	D1-A6,-(SP)
	move.w	#$80,$DFF09A
	move.w	#$80,$DFF09C
	bsr.w	Play
	move.w	#$8080,$DFF09A
	movem.l	(SP)+,D1-A6
	moveq	#0,D0
	rts

***************************************************************************
***************************************************************************
***************************************************************************

; Music from "Crazy Cars" (c) 1987 by Titus

Play
Init
	lea	$DFF000,A6
	lea	Sample+48(PC),A0
	move.l	A0,$A0(A6)
	move.w	#$FB6B,$A4(A6)
	move.w	#$165,$A6(A6)
	move.w	#$40,$A8(A6)
	rts

Sample
	incbin	ram:noise0
CC_End